init config

2025-07-04 00:32:17 +02:00
commit 1a20402712
35 changed files with 2383 additions and 0 deletions
@@ -0,0 +1,64 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  autoreconfHook,
+  intltool,
+  libxml2,
+  pciutils,
+  pkg-config,
+  gtk2,
+  ddccontrol-db,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ddccontrol";
+  version = "1.0.3";
+
+  src = fetchFromGitHub {
+    owner = "ddccontrol";
+    repo = "ddccontrol";
+    rev = version;
+    sha256 = "sha256-qyD6i44yH3EufIW+LA/LBMW20Tejb49zvsDfv6YFD6c=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    intltool
+    pkg-config
+  ];
+
+  buildInputs = [
+    libxml2
+    pciutils
+    gtk2
+    ddccontrol-db
+  ];
+
+  configureFlags = [
+    "--with-systemdsystemunitdir=${placeholder "out"}/etc/systemd/system"
+  ];
+
+  prePatch = ''
+    substituteInPlace configure.ac              \
+      --replace                                 \
+      "\$""{datadir}/ddccontrol-db"             \
+      "${ddccontrol-db}/share/ddccontrol-db"
+
+    substituteInPlace src/ddcpci/Makefile.am    \
+       --replace "chmod 4711" "chmod 0711"
+  '';
+
+  preConfigure = ''
+    intltoolize --force
+  '';
+
+  meta = with lib; {
+    description = "Program used to control monitor parameters by software";
+    homepage = "https://github.com/ddccontrol/ddccontrol";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = with lib.maintainers; [ pakhfn ];
+  };
+}