Laurent ZuijdwijkandMarshall
ba8818cbf3
* vulkan: handle larger batch sizes (>4) efficiently for IQ3_S mat-vec when NUM_COLS > 4. 5x perf at n=8 Assisted-by: Claude Opus 5 * adds 2 cases per quant type at `k=16*256` to the `all_types` mat-vec sweep --------- Co-authored-by: Marshall <assistant@llama.cpp>
94 lines
4.0 KiB
Plaintext
94 lines
4.0 KiB
Plaintext
#version 450
|
|
#extension GL_EXT_shader_explicit_arithmetic_types_int32 : require
|
|
|
|
#include "mul_mat_vec_base.glsl"
|
|
|
|
layout(local_size_x_id = 0, local_size_y = 1, local_size_z = 1) in;
|
|
|
|
FLOAT_TYPE temp[NUM_COLS][NUM_ROWS];
|
|
|
|
// invocations per superblock. with many columns, 8 invocations need too many
|
|
// registers and spill, so use 16 to halve the per-invocation B working set
|
|
const uint TPB = NUM_COLS <= 4 ? 8 : 16;
|
|
const uint NL = 32 / TPB; // l steps per invocation
|
|
|
|
void calc_superblock(const uint a_offset, const uint b_offset, const uint itid, const uint i, const uint num_blocks_per_row, const uint first_row, const uint num_rows) {
|
|
const uint ib32 = itid / (TPB / 8);
|
|
const uint l0 = (itid % (TPB / 8)) * NL;
|
|
const uint y_idx = i * QUANT_K + 32 * ib32;
|
|
|
|
uint ibi = a_offset + first_row * num_blocks_per_row + i;
|
|
[[unroll]] for (uint n = 0; n < num_rows; ++n) {
|
|
const float d = float(data_a[ibi].d);
|
|
const uint scale = (data_a[ibi].scales[ib32/2] >> (4 * (ib32 & 1))) & 0xF;
|
|
const float dscale = d * (1 + 2 * scale);
|
|
const uint qh = data_a[ibi].qh[ib32];
|
|
[[unroll]] for (uint ll = 0; ll < NL; ++ll) {
|
|
const uint l = l0 + ll;
|
|
const u8vec2 qs = unpack8(uint32_t(data_a_packed16[ibi].qs[4 * ib32 + l])).xy; // vec4 used due to #12147
|
|
const uint sign = data_a[ibi].signs[4 * ib32 + l];
|
|
const vec4 grid0 = vec4(unpack8(iq3s_grid[qs.x | ((qh << (8 - 2*l)) & 0x100)]));
|
|
const vec4 grid1 = vec4(unpack8(iq3s_grid[qs.y | ((qh << (7 - 2*l)) & 0x100)]));
|
|
|
|
[[unroll]] for (uint j = 0; j < NUM_COLS; ++j) {
|
|
const vec4 b0 = vec4(data_b_v4[(j*p.batch_stride_b + b_offset + y_idx) / 4 + 2*l + 0]);
|
|
const vec4 b4 = vec4(data_b_v4[(j*p.batch_stride_b + b_offset + y_idx) / 4 + 2*l + 1]);
|
|
|
|
const FLOAT_TYPE sum =
|
|
fma(FLOAT_TYPE(b0.x), FLOAT_TYPE((sign & 1) != 0 ? -grid0.x : grid0.x),
|
|
fma(FLOAT_TYPE(b0.y), FLOAT_TYPE((sign & 2) != 0 ? -grid0.y : grid0.y),
|
|
fma(FLOAT_TYPE(b0.z), FLOAT_TYPE((sign & 4) != 0 ? -grid0.z : grid0.z),
|
|
fma(FLOAT_TYPE(b0.w), FLOAT_TYPE((sign & 8) != 0 ? -grid0.w : grid0.w),
|
|
fma(FLOAT_TYPE(b4.x), FLOAT_TYPE((sign & 16) != 0 ? -grid1.x : grid1.x),
|
|
fma(FLOAT_TYPE(b4.y), FLOAT_TYPE((sign & 32) != 0 ? -grid1.y : grid1.y),
|
|
fma(FLOAT_TYPE(b4.z), FLOAT_TYPE((sign & 64) != 0 ? -grid1.z : grid1.z),
|
|
fma(FLOAT_TYPE(b4.w), FLOAT_TYPE((sign & 128) != 0 ? -grid1.w : grid1.w),
|
|
FLOAT_TYPE(0.0)))))))));
|
|
|
|
temp[j][n] = fma(dscale, sum, temp[j][n]);
|
|
}
|
|
}
|
|
ibi += num_blocks_per_row;
|
|
}
|
|
}
|
|
|
|
void compute_outputs(const uint32_t first_row, const uint32_t num_rows) {
|
|
uint a_offset, b_offset, d_offset;
|
|
get_offsets(a_offset, b_offset, d_offset);
|
|
|
|
const uint num_blocks_per_row = p.ncols / QUANT_K;
|
|
|
|
// TPB invocations are used to process each block
|
|
const uint blocks_per_wg = gl_WorkGroupSize.x/TPB;
|
|
const uint tid = gl_LocalInvocationID.x;
|
|
const uint itid = tid % TPB;
|
|
const uint ix = tid / TPB;
|
|
|
|
[[unroll]] for (uint j = 0; j < NUM_COLS; ++j) {
|
|
[[unroll]] for (uint i = 0; i < NUM_ROWS; ++i) {
|
|
temp[j][i] = FLOAT_TYPE(0);
|
|
}
|
|
}
|
|
|
|
[[unroll]] for (uint i = ix; i < num_blocks_per_row; i += blocks_per_wg)
|
|
calc_superblock(a_offset, b_offset, itid, i, num_blocks_per_row, first_row, num_rows);
|
|
|
|
reduce_result(temp, d_offset, first_row, num_rows, tid);
|
|
}
|
|
|
|
void main() {
|
|
const uint first_row = NUM_ROWS * (gl_WorkGroupID.x + gl_NumWorkGroups.x * gl_WorkGroupID.z);
|
|
|
|
init_iq_shmem(gl_WorkGroupSize);
|
|
|
|
// do NUM_ROWS at a time, unless there aren't enough remaining rows
|
|
if (first_row + NUM_ROWS <= p.stride_d) {
|
|
compute_outputs(first_row, NUM_ROWS);
|
|
} else {
|
|
if (first_row >= p.stride_d) {
|
|
return;
|
|
}
|
|
compute_outputs(first_row, p.stride_d - first_row);
|
|
}
|
|
}
|