AclyandJeff Bolz
e29acf74fe
* vulkan (DRAFT): split shader generation by GLSL source file, to improve incremental build times * support dep-files so shaders are recompiled if their included files change * rename shader files which are used as "headers" to use .glsl extension * move glslc extension detection shaders to separate folders * the above is to prevent them from getting glob'd with the actual compute shaders that need to be compiled * vulkan : only write embedded shader .hpp/.cpp when they change * avoid recompiling ggml-vulkan.cpp when editing shaders * pass single --source argument instead of --input-dir & --filter to shader gen * check for source file match earlier * fix hang in vulkan-shaders-gen when there are compilation errors * early out did not decrement compile_count * clean up * fix glslc integer dot product test * unconditionally write the embedded shader cpp output * replace output filepath in generated dep-files to match output in CMakeLists --------- Co-authored-by: Jeff Bolz <jbolz@nvidia.com>
67 lines
1.7 KiB
Plaintext
67 lines
1.7 KiB
Plaintext
#version 450
|
|
|
|
#include "generic_head.glsl"
|
|
#include "types.glsl"
|
|
|
|
#extension GL_EXT_control_flow_attributes : enable
|
|
#define BLOCK_SIZE 512
|
|
|
|
layout(local_size_x = BLOCK_SIZE, local_size_y = 1, local_size_z = 1) in;
|
|
|
|
layout (binding = 0) readonly buffer X {A_TYPE data_a[];};
|
|
layout (binding = 1) writeonly buffer D {D_TYPE data_d[];};
|
|
|
|
shared float tmp[BLOCK_SIZE];
|
|
|
|
void main() {
|
|
const uint group_size = p.KX;
|
|
const float eps = p.param1;
|
|
|
|
const uint tid = gl_LocalInvocationID.x;
|
|
const uint start = gl_WorkGroupID.x * group_size + tid;
|
|
const uint end = (gl_WorkGroupID.x + 1) * group_size;
|
|
|
|
tmp[tid] = 0.0f;
|
|
|
|
// Calculate mean
|
|
[[unroll]] for (uint col = start; col < end; col += BLOCK_SIZE) {
|
|
tmp[tid] += float(data_a[col]);
|
|
}
|
|
|
|
// tmp up partial tmps and write back result
|
|
barrier();
|
|
[[unroll]] for (int s = BLOCK_SIZE / 2; s > 0; s >>= 1) {
|
|
if (tid < s) {
|
|
tmp[tid] += tmp[tid + s];
|
|
}
|
|
barrier();
|
|
}
|
|
|
|
const float mean = tmp[0] / group_size;
|
|
barrier();
|
|
tmp[tid] = 0.0f;
|
|
|
|
// Calculate variance
|
|
[[unroll]] for (uint col = start; col < end; col += BLOCK_SIZE) {
|
|
const float xi = float(data_a[col]) - mean;
|
|
data_d[col] = D_TYPE(xi);
|
|
tmp[tid] += xi * xi;
|
|
}
|
|
|
|
// sum up partial sums and write back result
|
|
barrier();
|
|
[[unroll]] for (int s = BLOCK_SIZE / 2; s > 0; s >>= 1) {
|
|
if (tid < s) {
|
|
tmp[tid] += tmp[tid + s];
|
|
}
|
|
barrier();
|
|
}
|
|
|
|
const float variance = tmp[0] / group_size;
|
|
const float scale = inversesqrt(variance + eps);
|
|
|
|
[[unroll]] for (uint col = start; col < end; col += BLOCK_SIZE) {
|
|
data_d[col] *= D_TYPE(scale);
|
|
}
|
|
}
|